Diccionario Visual Trilingue/VISUAL.iso/SHARED.DIR/10005_Language Buttons Script.ls

Text File | 1997-07-04 | 1.8 KB | 66 lines

global gTextLanguage, gHighLightPos, gHighLightPosC, gOldTextLanguage, gIndexChange, gContenuChange

on mouseDown
  set SpriteNums to [22, 21, 23, 26, 25, 27, 31, 40]
  set ButtonType to [1, 1, 1, 2, 2, 2, 3, 4]
  repeat with i = 1 to 8
    set SpriteNum to getAt(SpriteNums, i)
    if rollOver(SpriteNum) then
      if pushButtonScript(SpriteNum) then
        if getAt(ButtonType, i) = 1 then
          InterfaceChange(i)
        else
          if getAt(ButtonType, i) = 2 then
            TextChange(i - 3)
          else
            if getAt(ButtonType, i) = 3 then
              CancelLanguagePalette()
            else
              if not (gTextLanguage = gOldTextLanguage) then
                set gIndexChange to 1
                set gContenuChange to 1
              end if
              CloseLangPrefPalettes()
            end if
          end if
        end if
      end if
      return
    end if
  end repeat
end

on pushButtonScript SpriteNum
  set inside to 1
  set theName to the name of cast the castNum of sprite SpriteNum
  if (theName starts "I.ac.") or (theName starts "T.ac.") then
    set offset to 0
  else
    set offset to 1
  end if
  set the castNum of sprite SpriteNum to the castNum of sprite SpriteNum + offset
  updateStage()
  repeat while the mouseDown
    if rollOver(SpriteNum) then
      if not inside then
        set the castNum of sprite SpriteNum to the castNum of sprite SpriteNum + offset
        set inside to 1
        updateStage()
      end if
      next repeat
    end if
    if inside then
      set the castNum of sprite SpriteNum to the castNum of sprite SpriteNum - offset
      set inside to 0
      updateStage()
    end if
  end repeat
  if inside then
    set the castNum of sprite SpriteNum to the castNum of sprite SpriteNum - offset
    updateStage()
    return 1
  else
    return 0
  end if
end